home *** CD-ROM | disk | FTP | other *** search
/ IRIX 6.4 Applications 1997 August / SGI IRIX 6.4 Applications 1997 August.iso / dist / mmailp.idb / usr / lib / Zmail / bin / metasend.z / metasend
Encoding:
Text File  |  1997-01-22  |  14.4 KB  |  500 lines
  1. #!/bin/csh -fb
  2. # (The "-fb" might need to be changed to "-f" on some systems)
  3. #
  4. # Copyright (c) 1991 Bell Communications Research, Inc. (Bellcore)
  5. # 
  6. # Permission to use, copy, modify, and distribute this material 
  7. # for any purpose and without fee is hereby granted, provided 
  8. # that the above copyright notice and this permission notice 
  9. # appear in all copies, and that the name of Bellcore not be 
  10. # used in advertising or publicity pertaining to this 
  11. # material without the specific, prior written permission 
  12. # of an authorized representative of Bellcore.  BELLCORE 
  13. # MAKES NO REPRESENTATIONS ABOUT THE ACCURACY OR SUITABILITY 
  14. # OF THIS MATERIAL FOR ANY PURPOSE.  IT IS PROVIDED "AS IS", 
  15. # WITHOUT ANY EXPRESS OR IMPLIED WARRANTIES.
  16. #
  17.  
  18. if (! $?METAMAIL_TMPDIR) then
  19.     set METAMAIL_TMPDIR=/tmp
  20. endif
  21.  
  22. set hname = `hostname`
  23. set idctr=0
  24. set MustDelete=0
  25. set batchmode=0
  26. set multipart = 1
  27. if ($?SPLITSIZE) then
  28.     set splitsize=$SPLITSIZE
  29. else
  30.     set splitsize = 100000
  31. endif
  32. set outputfile = ""
  33. set multipartsubtype = "mixed"
  34. set cdescrip = "An object packed by metasend"
  35. set isentity=0
  36. set newid=`date | tr " :" "__"`
  37. set cid="<${newid}_$idctr@${hname}>"
  38. @ idctr++
  39.  
  40. while ($#argv > 0)
  41.     switch ("$1")
  42.         case "-S":
  43.             shift
  44.             if ($#argv == 0) then
  45.                 echo "-S requires a following argument, the SPLIT threshhold"
  46.                 exit -1
  47.             endif
  48.             set splitsize=$1
  49.             shift
  50.             breaksw
  51.         case "-b":
  52.             # Batch mode -- ALL args must be on command line
  53.             set batchmode = 1
  54.             shift
  55.             breaksw
  56.         case "-c":
  57.             shift
  58.             if ($#argv == 0) then
  59.                 echo "-c requires a following argument, the CC address"
  60.                 exit -1
  61.             endif
  62.             set cc="$1"
  63.             shift
  64.             breaksw
  65.         case "-i":
  66.             shift
  67.             if ($#argv == 0) then
  68.                 echo "-i requires a following argument, the Content-ID value"
  69.                 exit -1
  70.             endif
  71.             set cid=$1
  72.             shift
  73.             breaksw
  74.         case "-I":
  75.             shift
  76.             if ($#argv == 0) then
  77.                 echo "-I requires a following argument, the multipart Content-ID value"
  78.                 exit -1
  79.             endif
  80.             set multicid=$1
  81.             shift
  82.             breaksw
  83.         case "-s":
  84.             shift
  85.             if ($#argv == 0) then
  86.                 echo "-s requires a following argument, the SUBJECT"
  87.                 exit -1
  88.             endif
  89.             set subject="$1"
  90.             shift
  91.             breaksw
  92.         case "-t":
  93.             shift
  94.             if ($#argv == 0) then
  95.                 echo "-t requires a following argument, the TO address"
  96.                 exit -1
  97.             endif
  98.             set to="$1"
  99.             shift
  100.             breaksw
  101.         case "-F":
  102.             shift
  103.             if ($#argv == 0) then
  104.                 echo "-F requires a following argument, the FROM address"
  105.                 exit -1
  106.             endif
  107.             set from="$1"
  108.             shift
  109.             breaksw
  110.         case "-P":
  111.             shift
  112.             if ($#argv == 0) then
  113.                 echo "-P requires a following argument, the preamble file name"
  114.                 exit -1
  115.             endif
  116.             set preamblefile="$1"
  117.             shift
  118.             breaksw
  119.         case "-e":
  120.             shift
  121.             if ($#argv == 0) then
  122.                 echo "-e requires a following argument, the ENCODING value"
  123.                 exit -1
  124.             endif
  125.             set encode=$1
  126.             if ($encode == "base64") then
  127.         set encodingprog = "mimencode -b"
  128.             else if ($encode == "x-uue") then
  129.             set encodingprog = "uuencode mail-body"
  130.             else if ($encode == "7bit") then
  131.             set encodingprog = cat
  132.            else
  133.             set encodingprog = "mimencode -q"
  134.             set encode = "quoted-printable"
  135.            endif 
  136.            shift
  137.             breaksw
  138.         case "-f":
  139.             shift
  140.             if ($#argv == 0) then
  141.                 echo "-f requires a following argument, the DATA FILE"
  142.                 exit -1
  143.             endif
  144.             set datafile=$1
  145.             if (! -e  $datafile) then
  146.                 echo The file $datafile does not exist.
  147.                 exit -1
  148.             endif
  149.             shift
  150.             breaksw
  151.         case "-m":
  152.             shift
  153.             if ($#argv == 0) then
  154.                 echo "-m requires a following argument, the MIME CONTENT-TYPE"
  155.                 exit -1
  156.             endif
  157. #            set ctyperaw = $1
  158. #            set  ctype=`echo $ctyperaw | tr \" \'`
  159.     set ctype = "$1"
  160.     if (`echo $ctype | grep /` == "") then
  161.         echo "Invalid content-type specified"
  162.         exit -1
  163.     endif
  164.             shift
  165.             breaksw
  166.         case "-o":
  167.             shift
  168.             if ($#argv == 0) then
  169.                 echo "-o requires a following argument, the output file name"
  170.                 exit -1
  171.             endif
  172.             set outputfile="$1"
  173.             shift
  174.             breaksw
  175.         case "-/":
  176.             shift
  177.             if ($#argv == 0) then
  178.                 echo "-/ requires a following argument, the multipart subtype"
  179.                 exit -1
  180.             endif
  181.             set multipartsubtype="$1"
  182.             shift
  183.             breaksw
  184.         case "-D":
  185.             shift
  186.             if ($#argv == 0) then
  187.                 echo "-D requires a following argument, the Content-Description value"
  188.                 exit -1
  189.             endif
  190.             set cdescrip="$1"
  191.             shift
  192.             breaksw
  193.         case "-E":
  194.             set isentity=1
  195.             shift
  196.             breaksw
  197.         case "-z":
  198.             set MustDelete=1
  199.             shift
  200.             breaksw
  201.         case "-n":
  202.             if ($isentity) then
  203.               if (! $?encode) then 
  204.                 set encode=7bit
  205.                 set encodingprog=cat
  206.               endif
  207.               if (! $?ctype) then
  208.                   set ctype=bogus
  209.                   # Never used
  210.                endif
  211.     if ( ! $?datafile) then
  212.         echo One part is incomplete -- each part needs at least -f and -E
  213.         exit -1
  214.     endif
  215.             else 
  216.     if ( ! $?ctype || ! $?datafile) then
  217.         echo One part is incomplete -- each part needs at least -f and -m
  218.         exit -1
  219.     endif
  220.             endif
  221.     if (! $?encode) then
  222.             if ("$ctype" =~ text*) then
  223.                   set encodingprog = "mimencode -q"
  224.         set encode = "quoted-printable"
  225.             else
  226.                 set encode = base64
  227.                 set encodingprog = "mimencode -b"
  228.             endif
  229.     endif
  230.     set ctype${multipart} = "$ctype"
  231.     set datafile${multipart} = $datafile
  232.     set encode${multipart} = $encode
  233.     set cdescrip${multipart} = "$cdescrip"
  234.     set cid${multipart} = "$cid"
  235.     set isentity${multipart} = $isentity
  236.     set encodingprog${multipart} = "$encodingprog"
  237.     unset ctype
  238.     unset datafile
  239.     unset encode
  240.     unset encodingprog
  241.     set newid=`date | tr " :" "__"`
  242.     set cid="<${newid}_$idctr@${hname}>"
  243.     @ idctr++
  244.     set cdescrip = "An object packed by metasend"
  245.     set isentity=0
  246.             @  multipart++
  247.     shift
  248.     breaksw
  249.         default:
  250.             echo UNRECOGNIZED METASEND OPTION: $1
  251.             exit -1
  252.     endsw
  253. end
  254. if ($batchmode == 0) then
  255.     if (! $?to) then
  256.         echo -n "To: "
  257.         set to = $<
  258.     endif
  259.     if (! $?subject) then
  260.         echo -n "Subject: "
  261.         set subject = $<
  262.     endif
  263.     if (! $?cc) then
  264.         echo -n "CC: "
  265.         set cc = $<
  266.     endif
  267. anotherpart:
  268.     if (! $?ctype) then
  269.         echo -n "Content-type: "
  270. #        set ctyperaw = $<
  271. #        set  ctype=`echo $ctyperaw | tr \" \'`
  272.         set ctype = "$<"
  273.     endif
  274.     if (`echo $ctype | grep /` == "") then
  275.         echo "Invalid content-type specified"
  276.         unset ctype
  277.         goto anotherpart
  278.     endif
  279. #    if ($ctype != $ctyperaw)  echo Double  quotes not allowed, using $ctype
  280.     if (! $?datafile) then
  281.         getfile:
  282.         echo -n "Name of file containing $ctype data: "
  283.         set datafile = $<
  284.         if (! -e  $datafile) then
  285.             echo The file $datafile does not exist.
  286.             goto getfile
  287.         endif
  288.     endif
  289.     if (! $?encode) then
  290.         retry:
  291.         echo "Do you want to encode this data for sending through the mail?"
  292.         echo "  1 -- No, it is already in 7 bit ASCII"
  293.         echo "  2 -- Yes, encode in base64 (most efficient)"
  294.         echo "  3 -- Yes, encode in quoted-printable (less efficient, more readable)"
  295.         echo "  4 -- Yes, encode it using uuencode (not standard, being phased out)"
  296.         set encode=$<
  297.         switch ("$encode")
  298.             case 1:
  299.                 set encodingprog = cat
  300.       set encode = 7bit
  301.                 breaksw
  302.             case 2:
  303.                 set encodingprog = "mimencode -b"
  304.       set encode = base64
  305.                 breaksw
  306.             case 3:
  307.                 set encodingprog = "mimencode -q"
  308.       set encode = quoted-printable
  309.                 breaksw
  310.             case 4:
  311.                 set encodingprog = "uuencode $datafile"
  312.       set encode = x-uue
  313.                 breaksw
  314.             default:
  315.                 echo Unrecognized answer, please try again.
  316.                 goto retry
  317.         endsw
  318.     endif
  319.     echo -n "Do you want to include another file too (y/n) [n] ? "
  320.     set ans=$<
  321.     if  ("$ans" =~ y*) then
  322.     set ctype${multipart} = "$ctype"
  323.     set datafile${multipart} = $datafile
  324.     set encode${multipart} = $encode
  325.     set encodingprog${multipart} = "$encodingprog"
  326.     set cdescrip${multipart} = "$cdescrip"
  327.     set cid${multipart} = "$cid"
  328.     set isentity${multipart} = $isentity
  329.     set cdescrip = "An object packed by metasend"
  330.     set isentity=0
  331.     unset ctype
  332.     unset datafile
  333.     unset encode
  334.     unset encodingprog
  335.     set newid=`date | tr " :" "__"`
  336.     set cid="<${newid}_$idctr@${hname}>"
  337.     @ idctr++
  338.             @  multipart++
  339.             goto anotherpart
  340.      endif
  341. else
  342.     if ($outputfile == "") then
  343.       if (! $?to || ! $?subject || ! $?ctype || ! $?datafile) then
  344.         echo metasend: in batch mode, if output is not directed to a file,-t, -s, -f, and -m are all required
  345.         exit -1
  346.       endif
  347.     else
  348.       if (! $?datafile) then
  349.         echo metasend:  in batch mode, -f is required.
  350.       endif
  351.       if ($isentity) then
  352.         if (! $?ctype) then
  353.           set ctype=bogus
  354.           # will not be used anyway really
  355.         endif
  356.       endif
  357.       if (! $?ctype  ) then
  358.         echo metasend: in batch mode, with output directed to a file, -E or -m is required
  359.         exit -1
  360.       endif
  361.     endif    
  362.     if (! -e  $datafile) then
  363.         echo metasend:  The file $datafile does not exist
  364.         exit -1
  365.     endif
  366. #    if (! $?cc) set cc=""
  367. #     if ($ctype != $ctyperaw)  echo Double  quotes not allowed, using $ctype
  368.     if (! $?encode) then
  369.         if ("$ctype" =~ text*) then
  370.     set encodingprog = "mimencode -q"
  371.     set encode = "quoted-printable"
  372.         else
  373.             set encodingprog = "mimencode -b"
  374.             set encode = base64
  375.         endif
  376.     else if ($encode == "base64") then
  377.         set encodingprog = "mimencode -b"
  378.     else if ($encode == "x-uue") then
  379.         set encodingprog = "uuencode mail-body"
  380.     else if ($encode == "7bit") then
  381.         set encodingprog = cat
  382.     else
  383.         set encodingprog = "mimencode -q"
  384.         set encode = "quoted-printable"
  385.     endif
  386. endif
  387.  
  388. if (! $?encode) then
  389.         if ("$ctype" =~ text*) then
  390.     set encode = "quoted-printable"
  391.     set encodingprog = "mimencode -q"
  392.         else
  393.             set encode = base64
  394.             set encodingprog = "mimencode -b"
  395.         endif
  396. endif
  397. set ctype${multipart} = "$ctype"
  398. set datafile${multipart} = $datafile
  399. set encode${multipart} = $encode
  400. set cdescrip${multipart} = "$cdescrip"
  401. set cid${multipart} = "$cid"
  402. set isentity${multipart} = $isentity
  403. set encodingprog${multipart} = "$encodingprog"
  404.  
  405. set fname = ${METAMAIL_TMPDIR}/msend.$$
  406. echo "MIME-Version: 1.0" > $fname
  407. if ($?to) then
  408.     echo "To: " "$to" >> $fname
  409. endif
  410. if ($?subject) then
  411.     echo "Subject: " "$subject" >> $fname
  412. endif
  413. if ($?cc) then
  414.     echo "CC: " "$cc" >> $fname
  415. endif
  416. if ($?from) then
  417.     echo "From: " "$from" >> $fname
  418. endif
  419. if ($multipart > 1) then
  420.     set  boundary = ${hname}.$$.`date | tr "  " .`
  421.     set newid=`date | tr " :" "__"`
  422.     if ($?multicid) then
  423.         echo "Content-ID: $multicid"   >> $fname
  424.     else
  425.         echo "Content-ID: <${newid}_$idctr@${hname}>"   >> $fname
  426.         @ idctr++
  427.     endif
  428.     echo "Content-type: multipart/$multipartsubtype;" >> $fname
  429.     echo "    boundary="\"$boundary\" >> $fname
  430.     echo "" >> $fname
  431.     if ($?preamblefile) then
  432.         cat $preamblefile >> $fname
  433.     else
  434.         echo "This is  a multimedia message in MIME  format.  If you are reading this" >> $fname
  435.         echo "prefix, your mail reader does  not understand MIME.  You may wish" >> $fname
  436.         echo "to look into upgrading to a newer version of  your mail reader." >> $fname
  437.     endif
  438.     set i=1
  439.     set junkfile=${METAMAIL_TMPDIR}/mmjunk.$$
  440.     while  ($multipart >= $i)
  441.     echo "" >> $fname
  442.     echo --$boundary >> $fname
  443.     echo set isentity=\$isentity$i > $junkfile
  444.     source $junkfile
  445.     if (! $isentity) then
  446.         echo -n "Content-ID: "   >> $fname
  447.         echo echo \$cid$i \>\>  $fname > $junkfile
  448.         source $junkfile 
  449.         echo -n "Content-type: ">>$fname
  450.         echo echo \$ctype$i \>\>  $fname > $junkfile
  451.         source $junkfile 
  452.         echo -n "Content-Description: ">>$fname
  453.         echo echo \"\$cdescrip$i \" \>\>  $fname > $junkfile
  454.         source $junkfile 
  455.         echo -n "Content-Transfer-Encoding: " >>$fname
  456.         echo echo \$encode$i \>\> $fname > $junkfile
  457.         source $junkfile 
  458.         echo ""  >> $fname
  459.     endif
  460.     echo \$encodingprog$i \< \$datafile$i \>\> $fname > $junkfile
  461.     source $junkfile 
  462.     @ i++
  463.     end
  464.     rm $junkfile
  465.     echo "" >> $fname
  466.     echo --${boundary}-- >> $fname
  467.     echo "" >> $fname
  468. else 
  469.     if (! $isentity) then
  470.         echo "Content-ID: $cid"   >> $fname
  471.         echo "Content-type: " $ctype >> $fname
  472.         echo "Content-Description: " $cdescrip >> $fname
  473.         echo "Content-Transfer-Encoding: " $encode >> $fname
  474.     endif
  475.     echo  "" >> $fname
  476.     $encodingprog < $datafile >> $fname
  477.     # Ensure last line has trailing carriage return
  478.     echo "" >> $fname
  479. endif
  480. if ($outputfile == "") then
  481.     if ($batchmode == 0) echo -n "Delivering mail, please wait...  "
  482.     splitmail -s $splitsize -d $fname
  483.     if (! $status) then
  484.         if ($batchmode == 0) echo "Mail delivery apparently succeeded."
  485.         rm $fname
  486.     else if ($MustDelete == 1) then
  487.         echo Mail delivery failed
  488.         rm $fname
  489.         exit -1
  490.     else
  491.         echo Mail delivery failed, draft mail is in $fname
  492.         exit -1
  493.     endif
  494. else
  495.     mv $fname $outputfile
  496.     if ($status) exit -1
  497. endif
  498. exit 0
  499.  
  500.